home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Mind Run
/
Mind Run (1991)(Crealude)(FR)(M6)[!][CFI MINDRUM 91148].iso
/
st48.amos
/
st48.amosSourceCode
Wrap
AMOS Source Code
|
2008-12-15
|
41KB
|
1,135 lines
' St48 16 4 91
Set Buffer 20 : Close Workbench : Close Editor : Randomize Timer
If Exist("CFI:") : Dir$="CFI:" : Else Dir$="df0:" : End If
'
Dim TPTS(6),ZBUT(28),BBUT(28),ZBI(36),H(28),V(28),CPL(8,3)
Dim XB(2),YB(2),Z(36),CUR(12,9,2),PREF(5),F$(20)
Global TEST,TPTS(),TEMPS,PTS,APTS,NBK,NBI,NB,NBUT,ZBUT(),BBUT(),DIFF
Global BUT$,SG$,SA$,SB$,ZBI(),H(),V(),CPL(),XB(),YB(),Z(),CUR(),HCR,VCR
Global BBOULE,XT,YT,XH,YH,XR,YR,BCUR,HCURS,VCURS,XC,YC,XP,YP,CX,CY
Global BCP,CYCLETAPE,ETAPE,QST,MXETAPE,DIFF,DERANN$,ELTEMPS,GAUCHE
Global DUREE,VITESSE,BZN,MZ,ABANDON,RENOUV$,TSAB,TREN,LANGUE$,TEST$
Global LIGNE,DIT,PREF(),BOUTONS,BOUTONA,BOUTONB,FAITMUSE,FERMEDES,DERBOULE
Global BOULBK,CRSBK,FLCHBK,CERVBK,BASEBLOCK,F$(),DC,DIT8,DIT7,DEGARE$
'''''''''''''''''''''
TEST$="Stress" : TEST=2 : NBUT=1 : ZBUT(NBUT)=BZN+1 : INITEST
'
''''''''''''''''''''''' Boucle de test '''''''''''''''''''''''''''''''
While ETAPE<MXETAPE and Not ABANDON
PAUSEPOINTS : Exit If Param=3
VOISTEST : PTS=Max(2,Min(9,2*DIFF-1)) : METPOINTS
VITESSE=50 : DUREE=$FFFF : For X=1 To 36 : ZBI(X)=0 : Next : VIDCUR[1]
On QST Proc CARRNB,UNECOL,NBDEUF,CARRBUG,CLAVIER,LETTRDEUF,LETWIN,NBCERCLES
'''' au joueur ''''''''''''''''''''''''''''''''''''''''''''''''
'
BRUIT[0,0,"tiroircaiss2"] : If BOUTONB and(PREF(4)=1) Then PREF(4)=0
GAUCHE[3,45] : While Chanan(DERBOULE) : Wend
Update : Wait Vbl : Update Off
For N=1 To NB : Bob N,,,NBK+16 : Wait Vbl : Next : Bob Off : Wait Vbl : AJOUR
NETTOIE[1] : If PTS<APTS Then DESTROYTOUT
FAITTOTAL : F=Free
Wend
RETOUR
''''''''''''''' Questions de STRESS
Procedure CARRNB
BANQBI["F.Chiffr3","F.Rouges1a9"]
TEMPS[0] : PARLE["Nodigit",1]
FAITCARRE
EGAR2[-1]
N0=2+Rnd(NB-4) : TIRE[0] : For X=1 To NB
If DIFF<2 : N=X : Else TIRE[NB] : N=Param : End If
If N<>N0
K=N : If DIFF>2 : K=1+Rnd(8) : End If
Bob 1,H(K),V(K),N : Wait Vbl
EGAR2[5]
While Timer<DIT+55-10*DIFF : Wend
End If : Next : Bob Off
FAIREPON[N0,9] : BBUT(1)=N0 : TSAB=Timer+49
Do
REXAMCUR : If Param : Gosub R_CARRNB : Else Exit : End If
Loop
Pop Proc
'
''''''''''''''''' renouvellement '''''''''''''''
R_CARRNB:
EGAR2[5] : N=1+Rnd(8) : Bob 1,H(N),V(N),1+Rnd(NB-1) : Return
End Proc
Procedure UNECOL
BANQBI["F.Number1","F.Rouges1a0"]
PARLE["colour",1]
H0=375-DC : V0=20 : N=0
If DIFF<4
For Y=0 To 2 : H1=H0+26*(Y=1) : X1=2-(Y=1) : For X=0 To X1 : Inc N
H(N)=H1+52*X : V(N)=V0+43*Y : Next : Next
Else
V0=4 : For Y=0 To 3 : YB=(Y=1)+(Y=2) : H1=H0+26*YB : X1=2-YB
For X=0 To X1 : Inc N : H(N)=H1+52*X : V(N)=V0+42*Y
Next : Next
End If : NB=N
TIRE[0] : For X=1 To NB/2-1 : TIRE[10] : B=Param
AFFECTE[1,NB,B] : AFFECTE[1,NB,B+10] : Next
' tire le couple d'une seule couleur, or ou bleu
TIRE[10] : B=Param+10*Rnd(1) : N0=Param : Rem +Param*(Param=10)
AFFECTE[1,NB,B] : AFFECTE[1,NB,B]
Bob Update Off : For N=1 To NB : Bob N,H(N),V(N),ZBI(N) : Next : AJOUR
Bob Update On
EGAR2[-1]
For X=0 To 6-DIFF : Gosub R_UNECOL
While Timer<DIT+55-10*DIFF : Wend
Next
TEMPS[0] : FAIREPON[N0,10] : TSAB=Timer+49
Do
REXAMCUR : If Param : Gosub R_UNECOL : Else Exit : End If
Loop
Pop Proc
'
''''''''''''''''' renouvellement '''''''''''''''
R_UNECOL:
N1=1+Rnd(NB-1) : Repeat : N2=1+Rnd(NB-1) : Until N2<>N1
A=I Bob(N1) : Bob N1,,,I Bob(N2) : Wait Vbl : Bob N2,,,A : Wait Vbl
EGAR2[5] : Return
End Proc
Procedure NBDEUF
BANQBI["F.green","F.Rouges1a9"]
TEMPS[0] : PARLE["Digitwice",1]
EGAR2[-1]
FAITCARRE
' choisit un nb redoubl� et celui (�loign�) qu'il remplacera
N0=1+Rnd(NB-1) : Repeat : N1=1+Rnd(NB-1) : Until N1<>N0 and Abs(N0-N1)>2
TIRE[0] : For X=1 To NB
If DIFF<2 : N=X : Else TIRE[NB] : N=Param : End If
P=N : If N=N1 : P=N0 : End If
K=N : If DIFF>2 : K=1+Rnd(8) : End If
Bob 1,H(K),V(K),P
EGAR2[5]
While Timer<DIT+55-10*DIFF : Wend
Next : Bob Off
FAIREPON[N0,9] : BBUT(1)=N0 : TSAB=Timer+49
Do
REXAMCUR : If Param : Gosub R_NBDEUF : Else Exit : End If
Loop
Pop Proc
'
''''''''''''''''' renouvellement '''''''''''''''
R_NBDEUF:
EGAR2[5] : N=1+Rnd(8) : Bob 1,H(N),V(N),1+Rnd(X-1) : Return
End Proc
Procedure LETTRDEUF
BANQBI["F.Reflex5","F.LiliRouge"]
TEMPS[0] : PARLE["lettertwice",1] : EGAR2[-3]
FAITCARRE
' fait une suite de lettres
TIRE[0] : For X=1 To NB : TIRE[26] : Z(X-1)=Param : Next
For X=NB To 36 : Z(X)=100 : Next
' choisit un nb � redoubler et celui (�loign�) qu'il remplacera
N0=1+Rnd(NB-1) : Repeat : N1=1+Rnd(NB-1) : Until N1<>N0 and Abs(N0-N1)>2
NM=Z(N0-1)
TIRE[0] : For X=1 To NB
N=X : If DIFF>1 Then TIRE[NB] : N=Param
P=N : If N=N1 : P=N0 : End If : Bob 1,H(N),V(N),Z(P-1)
EGAR2[5]
While Timer<DIT+55-10*DIFF : Wend
Next : Bob Off
'
Del Cblock 1 : Get Cblock 1,334-DC,170,300,50
Sort Z(0) : N0=Match(Z(0),NM) : VIDCUR[1]
For X=0 To 8 : H=350-DC+25*X : V=170 : Paste Icon H,V,NBI+Z(X)
CY=0 : CX=X+1 : CUR(CX,CY,0)=H : CUR(CX,CY,1)=163
CUR(CX,CY,2)=0 : If CX=N0+1 Then CUR(CX,CY,2)=BZN+1
Next : INICURS[1,0] : VCR=2 : HCR=9
Del Icon NBI+1 To Length(2)
TSAB=Timer+49
Do
REXAMCUR : If Param : Gosub R_LETTRDEUF : Else Exit : End If
Loop
Pop Proc
'
R_LETTRDEUF:
EGAR2[5] : Return
End Proc
Procedure LETWIN
BANQBI["F.Lettre1","F.LiliRouge"]
TEMPS[0] : PARLE["notwin",1] : EGAR2[-3]
' fait une suite de lettres : 4 couples et 1 solitaire
FAITCARRE : For N=1 To NB : ZBI(N)=0 : Z(N)=0 : Next : TIRE[0]
For X=1 To 4
TIRE[26] : I=Param : AFFECTE[1,9,I] : AFFECTE[1,9,I] : Z(X-1)=I
Next
TIRE[26] : N0=Param : AFFECTE[1,9,N0] : Z(4)=N0
For N=1 To NB : Bob N,H(N),V(N),ZBI(N) : Next
'
For X=0 To 6-DIFF
Gosub R_LETWIN : While Timer<DIT+55-10*DIFF : Wend
Next
' Compl�te et affiche les r�ponses possibles
For X=5 To 8 : TIRE[26] : Z(X)=Param : Next
For X=9 To 36 : Z(X)=200 : Next : Rem pour rendre le sort efficace
Sort Z(0) : N1=Match(Z(0),N0)
Del Cblock 1 : Get Cblock 1,334-DC,170,300,50
For X=0 To 8 : H=350-DC+25*X : V=170 : Paste Icon H,V,NBI+Z(X)
CY=0 : CX=X+1 : CUR(CX,CY,0)=H : CUR(CX,CY,1)=163
CUR(CX,CY,2)=0 : If CX=N1+1 Then CUR(CX,CY,2)=BZN+1
Next : INICURS[1,0] : VCR=2 : HCR=9
Del Icon NBI+1 To Length(2)
TSAB=Timer+49
Do
REXAMCUR : If Param : Gosub R_LETWIN : Else Exit : End If
Loop
Pop Proc
'
R_LETWIN:
EGAR2[5]
N1=Rnd(8)+1 : Repeat : N2=Rnd(8)+1 : Until Abs(N2-N1)>2
Swap ZBI(N1),ZBI(N2) : Bob N1,,,ZBI(N1) : Bob N2,,,ZBI(N2) : Return
End Proc
Procedure NBCERCLES
TEMPS[0]
Erase 2 : Load "BanqueI/F.cercles.abk",2 : NBD=Length(2)-1
PARLE["circles",1] : EGAR2[-2]
NB=9+DIFF+Rnd(DIFF)
Get Block BASEBLOCK+1,375-DC,10,200,170,1
H0=375-DC : V0=10 : N0=1+Min(7,Rnd(2*DIFF)) : C=80
For N=1 To N0+11 : Paste Icon H0+Rnd(C+20),V0+Rnd(C),1+Rnd(NBD) : Next
For X=1 To 8-DIFF
EGAR2[4]
While Timer<DIT+55-10*DIFF : Wend
Next
ABLOC[BASEBLOCK+1] : Del Block BASEBLOCK+1
Erase 2 : Load "banqueI/F.NB12a19.abk",2
' mettre des nombres entre 12 et 19 et ajuster N0
Del Cblock 1 : Get Cblock 1,328-DC,172,306,30 : Paste Icon 345-DC,172,1
BANQBI["",""]
CY=0 : For CX=1 To 8 : CUR(CX,CY,0)=340-DC+(CX-1)*35 : CUR(CX,CY,1)=163
CUR(CX,CY,2)=0 : If CX=N0 Then CUR(CX,CY,2)=BZN+1
Next
INICURS[1,0] : VCR=2 : HCR=8
'BBUT(1)=N0
TSAB=Timer+49
Do
REXAMCUR : If Param : Gosub R_NBCERCLES : Else Exit : End If
Loop
Pop Proc
'
R_NBCERCLES:
EGAR2[4] : Return
End Proc
Procedure CLAVIER
Erase 1 : Erase 2
Del Cblock 1 : Get Cblock 1,346-DC,36,268,148
Load "BanqueI/F.clavier.abk" : Paste Icon 347-DC,37,1
BANQBI["","F.Touches"]
N=0 : H0=351-DC : V0=88 : VIDCUR[1]
S$="AZERTYUIOPQSDFGHJKL\WXCVBNM"
'S$="ABCDEFGHIJKLMNOPQRSTUVWXYZ\"
For CY=0 To 2 : For X=0 To 9-CY : Inc N
H(N)=H0+25*X+7*CY : V(N)=V0+25*CY
ZBI(N)=NBI+N : Paste Icon H(N),V(N),NBI+N : Z(N)=Asc(Mid$(S$,N,1))
CX=X+1 : CUR(CX,CY,0)=H(N)-5 : CUR(CX,CY,1)=V(N)-5
CUR(CX,CY,2)=BZN+N
Next : Next : NB=N : ZBI(0)=NBI+28 : VCR=2 : HCR=10 : INICURS[1,0]
TEMPS[0] : PARLE["type",0]
CL: Data "TITANIC","KRAKATOA","BERMUDA","POMPEI","WATERLOO","ATTILA"
Data "VESUVIO"
Restore CL : For X=0 To Rnd(6) : Read BUT$ : Next : L=Len(BUT$)
For Y=0 To 3 : For X=1 To L : M=Asc(Mid$(BUT$,X,1)) : N=0
Repeat : Inc N : Until Z(N)=M : Paste Icon 367-DC+X*20,47,ZBI(N)+28
If X>1 : Paste Icon 367-DC+20*(X-1),47,ZBI(N0) : End If
N0=N : Next : Paste Icon 367-DC+20*(X-1),47,ZBI(N0) : Next
For X=0 To 8 : Paste Icon 386-DC+20*X,47,ZBI(0) : Next
While Timer<DIT : Wend
EGAR2[-3]
VITESSE=50 : SG$="" : TSAB=Timer+49
Do
FAIPREUVECUR : Exit If Param=0
On Param Gosub R_CLAVIER,F_CLAVIER
Loop
Pop Proc
'
F_CLAVIER:
TSAB0=TSAB-Timer : A=MZ-BZN : L=Len(SG$)
Paste Icon H(A),V(A),ZBI(A)+28 : BRUITB[3]
If(Z(A)=92) and(L>0)
SG$=Left$(SG$,L-1) : Paste Icon 386-DC+20*(L-1),47,ZBI(0)
End If
If(Z(A)<92) and(L<9)
SG$=SG$+Chr$(Z(A)) : Paste Icon 367-DC+20*(L+1),47,ZBI(A)
End If
While Mouse Key : Wend : Paste Icon H(A),V(A),ZBI(A)
TSAB=TSAB0+Timer : Return
'
R_CLAVIER:
EGAR2[5]
N1=Rnd(NB-1)+1 : Repeat : N2=Rnd(NB-1)+1 : Until Abs(N2-N1)>2
Swap ZBI(N1),ZBI(N2) : Swap Z(N1),Z(N2)
Paste Icon H(N1),V(N1),ZBI(N1) : Paste Icon H(N2),V(N2),ZBI(N2)
Return
End Proc
Procedure CARRBUG
Del Cblock 1 : Get Cblock 1,346-DC,10,200,172
Get Cblock 2,536-DC,108,84,78
BANQBI["F.CoccB","F.CoccI"] : Paste Icon 347-DC,10,Length(2)
H0=537-DC : V0=110 : F=0 : VIDCUR[1]
For CY=0 To 1 : For X=0 To 1 : Inc F : H(F)=H0+40*X : V(F)=V0+40*CY
ZBI(F)=NBI+F+1 : Z(F)=F : Paste Icon H(F),V(F),ZBI(F)
CX=X+1 : CUR(CX,CY,0)=H(F) : CUR(CX,CY,1)=V(F)
CUR(CX,CY,2)=BZN+F
Next : Next : HCR=2 : VCR=2
' H() et V() : 1 2 3 4 pour les fl�ches, 10 et plus pour le bug
H(10)=367-DC : V(10)=25 : H(11)=0 : V(11)=3
'
H(12)=1+Rnd(1) : V(12)=1+Rnd(1)
Paste Icon H(10)+33*H(12),V(10)+33*V(12),Length(2)-2
If DIFF>3
Repeat : H=Rnd(2) : V=Rnd(3)
Until((H<>H(12))+(V<>V(12)))*((H<>4)+(V<>0))*((H<>0)+(V<>4))
H(13)=H : V(13)=V
Paste Icon H(10)+33*H,V(10)+33*V,Length(2)-2
End If
'
H(14)=4 : V(14)=0 : Paste Icon H(10)+33*H(14),V(10)+33*V(14),Length(2)-1
Bob 1,H(10)+33*H(11),V(10)+33*V(11),1
PARLE["bug",1] : INICURS[2,0]
EGAR2[-4] : Del Icon Length(2)-2 To Length(2)
VITESSE=50-5*DIFF : BUT$="Cebon" : SG$=""
TSAB=Timer+49
Erase 8 : Reserve As Chip Work 8,10030
Bload "MRbruits/Crecelle0",Start(8)
Do
FAIPREUVECUR : Exit If Param=0
On Param Gosub R_CARRBUG,F_CARRBUG
Loop
VIDCUR[1] : Bob BCUR,CUR(0,0,0),CUR(0,0,1), : NETTOIE[2]
Del Cblock 2 : Wait 30 : Volume %101,0 : Erase 8
Pop Proc
'
F_CARRBUG:
TSAB0=TSAB-Timer : FL=MZ-BZN : F=Z(FL)
Paste Icon H(FL),V(FL),ZBI(FL)+8 : BRUITB[3]
H=H(11)-(F=4)+(F=3) : V=V(11)-(F=2)+(F=1)
If(H=H(14)) and(V=V(14)) Then SG$="Cebon"
A=(H>-1) and(H<4) and(V>-1) and(V<4) and((H<>H(12) or V<>V(12)))
If DIFF>3 Then A=A and(H<>H(13) or V<>V(13))
If((H=H(14)) and(V=V(14))) or A
While Timer<DIT8 : Wend
Sam Raw %1010,Start(8),10024,20000 : DIT8=Timer+27
Channel 1 To Bob 1 : Bob 1,H(10)+33*H(11),V(10)+33*V(11),F
Amal 1,"A 5,(R0,2)(R1,2);M R2,R3,20" : Amreg(1,0)=F+4 : Amreg(1,1)=F
Amreg(1,2)=33*(H-H(11)) : Amreg(1,3)=33*(V-V(11))
Amal On 1 : H(11)=H : V(11)=V
Else
Dec PTS : METPOINTS : DESTROYPT
End If
While Mouse Key : Wend : Paste Icon H(FL),V(FL),ZBI(FL)
TSAB=TSAB0+Timer : Return
'
R_CARRBUG:
EGAR2[4]
N1=Rnd(3)+1 : Repeat : N2=Rnd(3)+1 : Until N2<>N1
Swap ZBI(N1),ZBI(N2) : Swap Z(N1),Z(N2)
Paste Icon H(N1),V(N1),ZBI(N1) : Paste Icon H(N2),V(N2),ZBI(N2)
Return
End Proc
'
Procedure FAITCARRE
NB=9 : H0=375-DC : V0=10 : For Y=0 To 2 : For X=0 To 2 : Inc N
H(N)=H0+52*X : V(N)=V0+52*Y
Next : Next
End Proc
Procedure EGAR2[NS]
If NS<0 Then While Timer<DIT : Wend
If NS=-1 : Rem nombres de 1�9
S$=Mid$("FM",1+Rnd(1),1)+Str$(1+Rnd(1))-" "
DEGARE$="Egare/chif"+LANGUE$+S$+".sbk" : Load DEGARE$,6
Pop Proc : End If
If NS=-2 : Rem Nombresm de 11 � 20
S$=Mid$("FM",1+Rnd(1),1)+Str$(3+Rnd(1))-" "
DEGARE$="Egare/chif"+LANGUE$+S$+".sbk" : Load DEGARE$,6
Pop Proc : End If
If NS=-3 : Rem lettres
S$=Mid$("FM",1+Rnd(1),1)+Str$(1+Rnd(4))-" "
DEGARE$="Egare/Lett"+LANGUE$+S$+".sbk" : Load DEGARE$,6
Pop Proc : End If
If NS=-4 : Rem Directions
S$=Mid$("FM",1+Rnd(1),1)
DEGARE$="Egare/Direct"+LANGUE$+S$+".sbk" : Load DEGARE$,6
Pop Proc : End If
S0=Start(6) : X=1+Rnd(NS-1) : S=Leek(S0+8*X) : L=Leek(S0+8*X+4)
Sam Raw %101,S+S0+105,L-105,20000 : DIT=Timer+L/400
End Proc
Procedure AIDE
While Timer<DIT : Wend
PARLE[DERANN$,1] : While Timer<DIT : Wend : Wait 50 : Load DEGARE$,6
End Proc
Procedure FAIREPON[N0,NTOT]
Del Cblock 1 : Get Cblock 1,334-DC,175,300,50
Paste Icon 350-DC,175,NBI+1 : Del Icon NBI+1
CY=0 : For CX=1 To NTOT : CUR(CX,CY,0)=320-DC+25*CX : CUR(CX,CY,1)=163
CUR(CX,CY,2)=0 : If CX=N0 Then CUR(CX,CY,2)=BZN+1
Next
INICURS[1,0] : VCR=2 : HCR=NTOT
End Proc
Procedure FAIPREUVECUR
TREN=Timer+VITESSE : OPTION=0
Do
If SG$=BUT$ Then BRUITB[1] : While Timer<DIT7 : Wend : Exit
CURSEUR[1]
Exit If PTS<1
If(PTS<1) or(DUREE<1) Then OPTION=0 : Exit
If BOUTONB Then MZ=1
If Not(BOUTONS) Then OPTION=1 : Exit : Rem renouvelle
If(MZ=1) or BOUTONB Then CLIQUE[13] : PTS=0 : Exit : Rem Puis destroytout
If MZ=2 Then CLIQUE[14] : AIDE
If MZ=3 Then CLIQUE[15] : PTS=0 : ABANDON=True : Exit
If MZ>BZN Then BRUITB[100] : OPTION=2 : Exit 1
Loop
End Proc[OPTION]
Procedure REXAMCUR
TREN=Timer+VITESSE : RENOU=False
Do
CURSEUR[1] : Exit If PTS<1
If BOUTONB Then MZ=1
If Not(BOUTONS) Then RENOU=(PTS>0) : Exit
If MZ=1 Then CLIQUE[13] : PTS=0 : Exit : Rem Destroytout
If MZ=2
CLIQUE[14] : AIDE : INICURS[CX,CY] : BOUTONS=False
End If
If MZ=3 Then CLIQUE[15] : PTS=0 : ABANDON=True : Exit
Exit If PTS<1
If MZ=BZN+1 and BOUTONS
BRUITB[1] : While Timer<DIT7 : Wend : Exit
Else
TSAB0=TSAB-Timer : TREN0=TREN-Timer
Dec PTS : METPOINTS : DESTROYPT : RENOU=False
If DIFF>1 : Dec PTS : METPOINTS : DESTROYPT : Exit If PTS<1 : End If
If DIFF>3 : Dec PTS : METPOINTS : DESTROYPT : Exit If PTS<1 : End If
TSAB=TSAB0+Timer : TREN=TREN0+Timer : While Mouse Key : Wend
If PTS<1
Exit
Else
'While Timer<DIT7 : Wend
End If
End If
If Timer>Max(DIT,TREN) Then RENOU=True : Exit
Loop
End Proc[RENOU]
Procedure ALEAMUS[S]
If S=0 Then Volume %101,0 : FAITMUSE=0 : Pop Proc
While Timer<DIT : Wend
FAITMUSE=1 : A$="mrsons/stressons/glisstress1" : Bload A$,Start(6)
Add DIT,150
End Proc
Procedure MUSE
If Length(6)<1 Then Reserve As Chip Work 6,$FFFF
If PREF(5)=1 Then Pop Proc
If FAITMUSE=0 Then Pop Proc
Data 196,207.65,220,233.08,246.94
Data 261.63,277.18,293.66,311.13,329.63,349.23,370,392,415.3
Data 440,466.16,493.88,523.25
N=1+Rnd(16) : Restore : For X=1 To N : Read F : Next : F=20000/392*F
L=21576 : VOIX=Rnd(1)+4*Rnd(1) : Volume VOIX,20+Rnd(13)
Sam Raw VOIX,Start(6)+104,L,F : DIT=Timer+50*L/F+Rnd(60)
End Proc
'
'
' PROCEDURES GENERALES
'
Procedure INITEST
DC=0 : Rem nouvelles coordonn�es / petit �cran
If Screen=7 : PRENDVAR
Else Load Iff "decors/"+Mid$(TEST$,1,2),0 : Double Buffer
LANGUE$="Ang" : PREF(1)=1 : PREF(3)=2 : End If
Colour 0,0 : Colour Back 0 : Wait Vbl : View
Hide On : Limit Mouse : MXETAPE=40 : CYCLETAPE=8 : GAUCHE=True : Curs Off
XB(0)=280 : YB(0)=46 : Rem Suite
XB(1)=295 : YB(1)=63 : Rem Help
XB(2)=278 : YB(2)=79 : Rem Encore
BCUR=63 : Rem N� de bob du curseur
XP=282 : YP=4 : APTS=0 : BBOULE=15 : Rem bob des points sur le boulier
XC=253 : YC=177 : Rem compteur d'�tapes
XT=209 : YT=24 : Rem compteur du total
BOULBK=1 : CRSBK=2 : FLCHBK=3 : CERVBK=4 : BASEBLOCK=4 : Rem Blocks de base
BZN=8
For X=1 To 15 : Erase X : Next
Erase 7 : Reserve As Chip Work 7,7520 : Load "MRbruits/Brt0.sbk",7
'
BANQBI["",""]
'
Reserve Zone 35 : Limit Mouse
ETAPE=0 : QST=ETAPE : DIFF=1 : ELTEMPS=100
'
' Boulier des points par �cran (Block BOULBK pour toutes les boules)
Get Block BOULBK,25+XP-DC,5+YP,10,10,1
'
' Compteur d'�tapes (Block CRSBK pour le curseur, initialis� ici)
HCURS=XC-DC : VCURS=YC-3*ETAPE : Get Block CRSBK,HCURS,VCURS,22,17,1
Paste Icon HCURS,VCURS,12
'
' Fl�ches (block FLCHBK, actualis� chaque fois)
'For I=0 To 2 : Set Zone I+1,XB(I)+7-DC,YB(I)+7 To XB(I)+19-DC,YB(I)+19
'Next
'
' Difficult� (Block CERVBK actualis� chaque fois, initialis� ici)
AZDIF: Data 284,172,311,183
Data 285,161,314,172
Data 284,149,317,161
Data 285,133,321,149
Data 285,113,326,133
Restore AZDIF : Read H,V,H1,V1 : Add H,-DC : Add H1,-DC
Get Block CERVBK,H,V,H1-H,V1-V,1 : DIFF[0,DIFF]
Restore AZDIF
'For Y=4 To 8 : Read H,V,H1,V1 : Set Zone Y,H,V To H1,V1 : Next
'
' Plage de travail (Block 1, de type "c")
'Get Cblock 1,334,0,300,290
Get Cblock 1,0,0,8,2
TEMPS[0] : PARLE["Start",2]
End Proc
Procedure PAUSEPOINTS
BZDIF: Data 284,172,311,183,285,161,314,172,284,149,317,161
Data 285,133,321,149,285,113,326,133
ALEAMUS[1] : A=0 : CX=1 : CY=0
If(PREF(4)=0) or(ETAPE<1)
Repeat
VIDCUR[0]
For I=0 To 2
CUR(1,I,0)=XB(I)-DC : CUR(1,I,1)=YB(I) : CUR(1,I,2)=I+1
Next
Restore BZDIF : For Y=4 To 8
Read H,V,H1,V1 : Add H,-DC : Add H1,-DC
CUR(1,11-Y,0)=H : CUR(1,11-Y,1)=V : CUR(1,Y-1,2)=12-Y : Next
CUR(0,2,0)=194-DC : CUR(0,2,1)=85 : CUR(0,2,2)=9
INICURS[CX,CY] : HCR=1 : VCR=7
CURSEUR[0] : A=Param : If BOUTONB : MZ=3 : End If
If(A=27) or(MZ=2) : Rem pr�sentations
ALEAMUS[0]
If MZ=2 : CLIQUE[14] : CX=1 : CY=1 : INICURS[CX,CY] : End If
DEPLACE: Data 1,0,1,1,1,2,0,2,1,2,1,1,1,0,1,1,1,2,1,3
Bob BCUR,CUR(1,0,0),CUR(1,0,1), : Wait Vbl : PARLE["Arrows",2]
Restore DEPLACE : For X=1 To 10
Read H,V
BRUITB[3] : Bob BCUR,CUR(H,V,0),CUR(H,V,1), : Wait Vbl
TEMPS=Timer+50
Repeat : K1=Mouse Key : Until Timer>TEMPS or K1>0
Exit If K1
Next
If K1<1
PRESENTE: Data 1,0,"Advance",1,1,"Help",1,2,"Main"
Data 0,2,"Preferences"
Wait 50 : PARLE["select",2] : Wait 250 : Restore PRESENTE
For X=1 To 4
Read H,V,A$ : Bob BCUR,CUR(H,V,0),CUR(H,V,1), : Wait Vbl
PARLE[A$,2]
T=Timer+250 : Repeat : K2=Mouse Key : Until Timer>T or K2>0
Exit If K2
Next
If K2<1
PARLE["Level",2] : Rem Amal Off 15 : Wait Vbl
For X=1 To 5 : Bob BCUR,CUR(1,8-X,0),CUR(1,8-X,1), : Wait Vbl
T=Timer+50
Repeat : K3=Mouse Key : Until Timer>T or K3>0
Exit If K3
Bob BCUR,,,NBK+16 : Wait Vbl : Rem AJOUR : DIFF[X]
'Bob BCUR,,,NBK+17 : Wait Vbl : Wait 40
Next
If K3<1
T=Timer+100
Repeat : K=Mouse Key : Until Timer>T or K>0
End If
End If
'DIFF[1]
End If
MZ=0 : INICURS[1,0] : ALEAMUS[1] : Wait 50
End If
If A=43
ETAPE=Min(39,ETAPE+1) : ETAPE[ETAPE] : Inc QST : MZ=0
End If
If A=45
ETAPE=Max(0,ETAPE-1) : ETAPE[ETAPE] : QST=Max(0,QST-1) : MZ=0
End If
If 3<MZ and MZ<9
BRUITB[100] : Amal Off 15 : Bob BCUR,,,NBK+16 : AJOUR : DIFF[DIFF,MZ-3]
End If
If MZ=9 : ALEAMUS[0] : BRUITB[50]
P=1 : If Screen=3 : P=2 : End If : PREFERENCES[P] : ALEAMUS[1]
MZ=0
End If
Until(MZ=1) or(MZ=3) or BOUTONB
Else
MZ=1
End If : ALEAMUS[0]
Wait 1+50*PREF(4) : Rem If(PREF(4)=1) and(ETAPE>0) Then MZ=1
If MZ=1
ALEAMUS[0] : DIT=0
CLIQUE[13] : Inc ETAPE : Inc QST
If QST>CYCLETAPE
A=DIFF : QST=1 : DIFF=Min(DIFF+1,5) : DIFF[A,DIFF]
End If
ETAPE[ETAPE] : TEMPS[0]
End If
If(MZ=3) or BOUTONB Then CLIQUE[15]
Amal Off 15 : Bob Off BCUR : Bob Clear : AJOUR
End Proc[MZ]
Procedure INICURS[CX,CY]
Limit Mouse
If Chanan(15) Then Bob BCUR,CUR(CX,CY,0),CUR(CX,CY,1), : Pop Proc
Channel 15 To Bob BCUR : Bob BCUR,CUR(CX,CY,0),CUR(CX,CY,1),NBK+17
Wait Vbl : Amal 15,"A 0,(R1,46)(R2,4)"
Amreg(15,1)=NBK+17 : Amreg(15,2)=NBK+18 : Amal On 15 : Clear Key
End Proc
Procedure CURSEUR[C]
BOUTONA=False : BOUTONB=False : BOUTONS=False
Clear Key
Repeat
Repeat : T1=Timer+50
For X=1 To 10
X=X Mouse : Y=Y Mouse : Wait 3 : U=X Mouse : V=Y Mouse
Exit If X=U and Y=V
Next
X Mouse=150 : Y Mouse=100 : MX0=X Mouse : MY0=Y Mouse : DM=0
Repeat
If Timer>DIT Then MUSE
If C=1 : Rem En cours de question
If Timer>TSAB : TEMPS[1] : TSAB=Timer+49 : End If
If(PTS<1) or(DUREE<1) : MZ=0 : Exit 3 : End If
If Timer>TREN : A=0 : Exit 3 : End If
End If
If C=2 : Rem En menu principal
If Timer>T1
Restore "ETOILE"
For X=1 To 1+Rnd(21) : Read A,B : Next
Bob 3,A,B, : Wait Vbl
T2=Timer+10+Rnd(20) : T1=T2+200
End If
If Timer>T2
Bob 3,-20,, : T1=Timer+50+50*Rnd(2) : T2=T1+200
End If
End If
MX=X Mouse : MY=Y Mouse : A$=Inkey$
Until A$<>"" or Mouse Key or Abs(MX0-MX)>DM or Abs(MY0-MY)>DM
K=Mouse Key : R=Asc(A$)
A=-28*(MX-MX0>DM)-29*(MX0-MX>DM)-30*(MY0-MY>DM)-31*(MY-MY0>DM)
If(R>27) and(R<32) Then A=R
X=CX : Y=CY
If(A=28) Then Add X,1
If(A=29) Then Add X,-1
If(A=30) Then Add Y,-1
If(A=31) Then Add Y,1
Until((X<0)+(Y<0)+(X>HCR)+(Y>VCR)=0)
If(X<>CX) or(Y<>CY)
If(CUR(X,Y,0)=0) and(CUR(X,Y,1)=0)
If(A=28) or(A=29)
Repeat : Add Y,-1,0 To VCR
Until((CUR(X,Y,0)<>0) or(CUR(X,Y,1)<>0))
End If
If(A=30) or(A=31)
Repeat : Add X,1,0 To HCR
Until((CUR(X,Y,0)<>0) or(CUR(X,Y,1)<>0))
End If
End If
BRUITB[3] : CX=X : CY=Y : Bob BCUR,CUR(CX,CY,0),CUR(CX,CY,1),
Exit If C=2
End If
Until(K>0)+(R=43)+(R=45)+(R=27)+(R=13)
MZ=CUR(CX,CY,2)
BOUTONS=(K>0)+(R=13) : BOUTONA=(K=1)+(K=3)+(R=13) : BOUTONB=(K>1)
End Proc[R]
Procedure VIDCUR[A]
For X=0 To 12 : For Y=0 To 9 : For Z=0 To 2 : CUR(X,Y,Z)=0
Next : Next : Next
If A=1 : Rem situe les trois fl�ches
For I=0 To 2 : CUR(0,I,0)=XB(I)-DC : CUR(0,I,1)=YB(I)
CUR(0,I,2)=I+1 : Next
HCR=1 : VCR=2
End If
End Proc
Procedure PARLE[A$,T]
If Length(6)<1 Then Reserve As Chip Work 6,$FFFF
If PREF(1)<1 Then Pop Proc
While Timer<DIT : Wend
Volume %101,63 : DERANN$=A$
T$=TEST$ : If T=2 Then T$="General"
SEX$=Mid$("FM",1+Rnd(1),1) : If Instr("JapIta",LANGUE$) Then SEX$="F"
F$="Paroles/"+T$+"/"+LANGUE$+SEX$+"/"+A$
If Not Exist(F$) Then Pop Proc
Open In 1,F$ : L=Lof(1) : Close 1
If L>$FFFF Then Pop Proc
S6=Start(6) : Bload F$,S6 : Volume %101,63 : Sam Raw %101,104+S6,L,20000
DIT=Timer+(L/400)+20
If Exist(F$+Chr$(50))
While Timer<DIT : Wend : F$=F$+Chr$(50)
Open In 1,F$ : L=Lof(1) : Close 1
If L>64000 : Pop Proc : End If
Bload F$,S6 : Sam Raw %101,104+S6,L,20000
DIT=Timer+(L/400)+20
End If
If T=1 Then While Timer<DIT : Wend
End Proc
Procedure BRUIT[F,V,A$]
If Length(6)<1 Then Reserve As Chip Work 6,$FFFF
If PREF(2) Then Pop Proc
While Timer<DIT : Wend
S=20000 : If F<>0 Then S=1000*F
If L>65430 Then Pop Proc
Open In 1,"MRbruits/"+A$ : L=Lof(1) : Close 1
Bload "MRbruits/"+A$,Start(6)
Volume %1010,63 : If V<>0 Then Volume %1010,V
Sam Raw %1010,Start(6)+104,L,S : DIT=Timer+L/400
End Proc
Procedure BRUITB[N]
F=20000 : If N=100 Then N=3 : F=30000
If N=50 Then N=3 : F=10000
S0=Start(7) : S=Leek(S0+8*N) : L=Leek(S0+8*N+4)
Volume %1010,63 : Sam Raw %1010,S+S0+105,L-105,F : DIT7=Timer+L/400
End Proc
Procedure TEMPS[T]
' Mettre sur la voix
If T=0 : TEMPS=DIFF-1 : Else BRUITB[2] : End If
Inc TEMPS
If TEMPS>10
Dec PTS : METPOINTS : DESTROYPT : Dec DUREE
If(DUREE<1) or(PTS<1) : Pop Proc : End If
TEMPS=DIFF
End If
Paste Icon 578-DC,5,TEMPS+15 : Wait Vbl
End Proc
Procedure CLIQUE[I]
Amal Off 1 : Bob Off BCUR : Bob Clear : AJOUR
BRUITB[50] : H=XB(I-13)-DC : V=YB(I-13)
Get Block FLCHBK,H,V,40,40,1 : Paste Icon H,V,I : While Mouse Key : Wend
ABLOC[FLCHBK]
End Proc
Procedure ETAPE[ETAPE]
Update : Update Off : Wait Vbl
Bob Clear : Put Block CRSBK,XC-DC, : Bob Draw : Screen Swap : Wait Vbl
Bob Clear : Put Block CRSBK,XC-DC, : Bob Draw : Screen Swap : Wait Vbl
Update On
HCURS=XC-DC : VCURS=YC-3*ETAPE
Get Block CRSBK,HCURS,VCURS,22,17,1 : Paste Icon HCURS,VCURS,12
End Proc
Procedure DIFF[I1,I2]
ZD1: Data 284,172,311,183
ZD2: Data 285,161,314,172
ZD3: Data 284,149,317,161
ZD4: Data 285,133,321,149
ZD5: Data 285,113,326,133
If I1>0
Restore "ZD"+Str$(I1)-" " : Read H : Add H,-DC
Update : Update Off : Wait Vbl
Bob Clear : Put Block CERVBK,H, : Bob Draw : Screen Swap : Wait Vbl
Bob Clear : Put Block CERVBK,H, : Bob Draw : Screen Swap : Wait Vbl
Update On
End If
I=Min(I2,5) : Restore "ZD"+Str$(I)-" " : Read H,V,H1,V1
Add H,-DC : Add H1,-DC
Get Block CERVBK,H,V,H1-H,V1-V,1 : Paste Icon H,V,6+I
DIFF=I
End Proc
Procedure FAITTOTAL
I=PTS : B=BBOULE
PT1: Data 25,5
PT2: Data 14,5
PT3: Data 3,5
PT4: Data 25,16
PT5: Data 14,16
PT6: Data 3,16
PT7: Data 25,27
PT8: Data 14,27
PT9: Data 3,27
If PTS>0
Amal Off : Bob Off : AJOUR
A$="A 1,(R2,7)(R3,1)(R4,1);M R0,0,5;M 0,R1,3;M -4,0,4"
For X=I To 1 Step -1
Dec PTS : METPOINTS : Inc TPTS(TEST)
Restore "PT"+Str$(PTS+1)-" " : Read H,V : H=XP+H-DC : V=YP+V
Dec B : Channel B To Bob B : Bob B,H,V,NBK+1 : Wait Vbl
Amal B,A$
Amreg(B,0)=XT+55-H-DC : Amreg(B,1)=YT+4-V : Amreg(B,2)=NBK+1
Amreg(B,3)=NBK+15 : Amreg(B,4)=NBK+16
Amal On B
If X=I : Sam Loop On : BRUIT[0,0,"Bobloc"] : End If
METTOTAL["+",TPTS(TEST),XT,YT] : Wait Vbl
Next
While Chanmv(B) : Wend
Bob Off : Bob Clear : Sam Loop Off
End If
End Proc
Procedure METTOTAL[D$,N,X0,Y0]
If D$="+" or N>0
U=N mod 10 : N=(N-U)/10
If N>0
D=N mod 10 : N=(N-D)/10
If N>0
C=N mod 10
End If
End If
Paste Icon X0-DC,Y0,27+C : Wait Vbl
Paste Icon X0+13-DC,Y0,27+D : Wait Vbl
Paste Icon X0+26-DC,Y0,27+U : Wait Vbl
Else
Paste Icon X0,Y0,26
Paste Icon X0+13,Y0,26
Paste Icon X0+26,Y0,26 : Paste Icon X0+26,Y0,26
End If
End Proc
Procedure METPOINTS
APT1: Data 25,5
APT2: Data 14,5
APT3: Data 3,5
APT4: Data 25,16
APT5: Data 14,16
APT6: Data 3,16
APT7: Data 25,27
APT8: Data 14,27
APT9: Data 3,27
If PTS<0 Then APTS=0 : Pop Proc
If PTS>APTS
For X=Max(1,APTS+1) To PTS
Restore "APT"+Str$(X)-" " : Read H,V : Paste Icon XP+H-DC,YP+V,1
Next
Else
For X=APTS To Max(PTS+1,1) Step -1
Restore "APT"+Str$(X)-" "
Read H,V : H=XP+H-DC : V=YP+V : AUTOBLOC[BOULBK,H,V]
Next
End If
APTS=PTS
End Proc
Procedure DESTROYPT
If PTS<0 Then Pop Proc
While FERMEDES : Wend : FERMEDES=True
BPT1: Data 25,5
BPT2: Data 14,5
BPT3: Data 3,5
BPT4: Data 25,16
BPT5: Data 14,16
BPT6: Data 3,16
BPT7: Data 25,27
BPT8: Data 14,27
BPT9: Data 3,27
BRUITB[4] : Restore "BPT"+Str$(PTS+1)-" " : Read H,V
B=BBOULE-1 : Dec BBOULE : If BBOULE=12 Then BBOULE=15
BL=B+20
DSP$="A 1,(R1,R0)(R1+1,R0)(R1+2,R0)(R1+3,R0)(R1+4,R0)(R1+5,R0)(R2,1)"
DSP$=DSP$+";M 0,100,62"
Channel B To Bob BL : Bob BL,XP+H-DC,YP+V,NBK+3 : Wait Vbl : Amal B,DSP$
Amreg(B,0)=10 : Amreg(B,1)=NBK+3 : Amreg(B,2)=NBK+16 : Amal On B
FERMEDES=False : DERBOULE=B
'While Chanmv(B) or Chanan(B) : Wend
End Proc
Procedure DESTROYTOUT
Data 25,5,14,5,3,5,25,16,14,16,3,16,25,27,14,27,3,27
If APTS<1 Then Pop Proc
BRUIT[0,0,"perdu!"] : Bob Off : Bob Clear : Amal Off
Restore : For P=1 To APTS : Read H,V
H(P)=XP+H-DC : V(P)=YP+V : AUTOBLOC[BOULBK,H(P),V(P)] : Next
For P=1 To APTS : Bob P,H(P),V(P),NBK+3 : Wait Vbl : Next
DSP$="A 1,(R1,R0)(R1+1,R0)(R1+2,R0)(R1+3,R0)(R1+4,R0)(R1+5,R0)(R1+13,1)"
DSP$=DSP$+";M 0,100,62"
For P=APTS To 1 Step -1
Channel P To Bob P : Bob P,H(P),V(P), : Wait Vbl
Amal P,DSP$ : Amreg(P,0)=10 : Amreg(P,1)=NBK+3 : Amal On P
Next
While Chanmv(1) or Chanan(1) : Wend : Wait Vbl : Wait 25
APTS=0 : PTS=0
End Proc
Procedure DROITE[E,D]
If Not(GAUCHE) Then Pop Proc
Amal Off : Wait Vbl
Channel 1 To Screen Offset E : Screen E : Screen To Front E
Amal 1,"M 20,0,5;M R0,0,R1;M 20,0,5"
Amreg(1,0)=D : Amreg(1,1)=20 : If D<100 Then Amreg(1,1)=5
Amal On 1 : While Chanmv(1) : Wend : GAUCHE=False
End Proc
Procedure GAUCHE[E,D]
If GAUCHE Then Pop Proc
Amal Off : Wait Vbl
Channel 1 To Screen Offset E : Screen E
Amal 1,"M -20,0,5 ;M R0,0,R1;M -20,0,5"
Amreg(1,0)=-D : Amreg(1,1)=20 : If D<100 Then Amreg(1,1)=5
Amal On 1 : While Chanmv(1) : Wend : GAUCHE=True
End Proc
Procedure DIAPHRAGME[A,B]
' montre la moiti� gauche de B arrivant en diaphragme sur A
Autoback 0 : Screen To Front A
For X=1 To 59 Step 2
H0=170-X : H1=170+X : V0=128-X : V1=128+X
Screen Swap : Wait Vbl : Screen Copy B,H0,V0,H1,V1 To A,H0,V0
Next
For X=60 To 130 Step 10
H0=170-X : H1=170+X : V0=128-X : V1=128+X
Screen Swap : Wait Vbl : Screen Copy B,H0,V0,H1,V1 To A,H0,V0
Next
For X=131 To 176 Step 20
H0=170-X : H1=170+X : V0=0 : V1=260
Screen Swap : Wait Vbl : Screen Copy B,H0,V0,H1,V1 To A,H0,V0
Next
Screen To Front B : Screen B : Rem Screen Close A
End Proc
Procedure CLOCK[X,Y]
Change Mouse 3 : X Mouse=X : Y Mouse=Y : Show On
End Proc
Procedure PASSECRAN[A$,E,F,G]
Screen Open 2,360,270,64,Lowres : Flash Off
Get Palette E : Screen To Front E
Screen Copy E,0,0,360,270 To 2,0,0 : Screen Close E
Load Iff A$,F : Flash Off : Get Palette 2
Screen To Front 2 : Screen F
Colour 0,0 : Colour Back 0 : Wait Vbl : View
If G=1 Then Screen Close 2 : Double Buffer
End Proc
Procedure BANQBI[B$,I$]
CLOCK[280,60] : Amal Off : Bob Off : AJOUR : Erase 1 : Erase 2
If B$=""
NBK=0 : Load "BanqueB/BoulesC.abk"
Else
Load "BanqueB/"+B$+".abk" : NBK=Length(1) : Load "BanqueB/BoulesC.abk",1
End If
Load "BanqueI/Ftdb.abk" : NBI=Length(2)
If I$<>"" Then Load "BanqueI/"+I$+".abk",2
Make Icon Mask : Hide On
End Proc
Procedure PREFERENCES[CHOIX]
PRFV: Data "voice","sounds","language","speed","music"
PRF1: Data 0,0,6,0,10,7,1,"voice"
PRF2: Data 1,0,69,0,73,7,2,"sounds"
PRF3: Data 1,1,37,15,41,21,3,"Language"
PRF4: Data 0,2,6,30,13,35,8,"speed"
PRF5: Data 1,2,69,30,74,35,9,"music"
DRAPEAUX: Data 3,4,6,0,11,5,0,0,0,0,0,0,7
DIALECTES: Data "Ang","Ang","All","Fra","Esp","Ita","","","","","","","Jap"
SUITE_D_OPTIONS: Data 2,3,4,5,6,13,4,4,4,4,4,4,1
CLOCK[300,150] : B$="A.PeTdbacc" : BANQBI[B$,""] : ZB=Length(1)+1 : TB=10
ECR=Screen : ZCR=4
Screen Open ZCR,112,66,64,Lowres : Flash Off
Screen ZCR : Flash Off : Get Palette ECR : Cls 0
Screen To Front ECR : Screen ZCR : Paste Bob 0,0,TB : Wait Vbl
For X=1 To 5 : Restore "PRF"+Str$(X)-" "
Read A,B,C,D,E,F,Z
If X=3
Restore DRAPEAUX : For XX=1 To PREF(3) : Read Z : Next
If Z=0 : Z=NBK+16 : End If : Paste Bob E,F,Z
Else
If PREF(X) : Paste Bob E,F,Z : End If
End If
Next : Get Bob ZCR,ZB,0,0 To 111,63 : Screen ECR
PARLE["Choose",2] : Hide On
If CHOIX=0 : H=40 : V=73
For Z=1 To 64 Step 2
ZZ=Min(2*Z,112) : Get Bob ZCR,ZB,0,0 To ZZ,Z : Bob 1,H,V,ZB : Wait Vbl
Next
Else
Bob 1,400,10,ZB : Wait Vbl
If CHOIX=1
Limit Bob 1,0,0 To 224,200
Channel 1 To Bob 1 : Bob 1,222,120, : Wait Vbl
Amal 1,"M -112,0,28" : Amal On 1 : While Chanmv(1) : Wend
H=110 : V=120
Else
Limit Bob 1,158,0 To 400,200
Channel 1 To Bob 1 : Bob 1,36,120, : Wait Vbl
Amal 1,"M 112,0,28" : Amal On 1 : While Chanmv(1) : Wend
H=148 : V=120
End If
End If
VIDCUR[0]
For X=1 To 5 : Restore "PRF"+Str$(X)-" "
Read A,B,C,D,E,F,Z : Add E,H : Add F,V
If X=3
Restore DRAPEAUX : For XX=1 To PREF(3) : Read Z : Next
If Z=0 : Z=NBK+16 : End If : Bob X+1,E,F,Z
Else
If PREF(X)
Bob X+1,E,F,Z
Else
Bob X+1,E,F,NBK+16
End If : Wait Vbl
End If
Next : Bob 1,,,TB : Wait Vbl
'
'
VIDCUR[0] : K=0
For X=1 To 5 : Restore "PRF"+Str$(X)-" "
Read A,B,C,D,E,F,Z,P$ : Add C,H : Add D,V
CUR(A,B,0)=C : CUR(A,B,1)=D : CUR(A,B,2)=X : Z(X)=Z
If K<1
Bob BCUR,CUR(A,B,0),CUR(A,B,1),NBK+17 : Wait Vbl : PARLE[P$,2]
TEMPS=Timer+50 : Repeat : K=Mouse Key : Until Timer>TEMPS or K>1
End If
Next
While Mouse Key : Wend
HCR=1 : VCR=2 : INICURS[1,1] : L$=LANGUE$
Do
CURSEUR[0] : If BOUTONB Then MZ=0 : BOUTONB=False
Exit If MZ=0 or Not(BOUTONS)
If MZ=3
Restore SUITE_D_OPTIONS : For X=1 To PREF(3) : Read PREF(3) : Next
Restore DIALECTES : For X=1 To PREF(3) : Read LANGUE$ : Next
Restore DRAPEAUX : For X=1 To PREF(3) : Read Z : Next
If Z=0 : Z=NBK+16 : End If
Bob MZ+1,,,Z : Wait Vbl
Else
If PREF(MZ)
Bob MZ+1,,,NBK+16 : PREF(MZ)=0
Else
Bob MZ+1,,,Z(MZ) : PREF(MZ)=1
End If
End If : Wait Vbl
Restore PRFV : For X=1 To MZ : Read P$ : Next : PARLE[P$,2]
While Mouse Key : Wend
Loop
FINDEPREF:
AJOUR : BRUITB[100] : Amal Off 15 : Bob BCUR,,,NBK+16 : Wait Vbl
CX=1 : CY=0
Screen ZCR : Paste Bob 0,0,TB
For X=1 To 5 : Restore "PRF"+Str$(X)-" "
Read A,B,C,D,E,F,Z
If X=3
Restore DRAPEAUX : For XX=1 To PREF(3) : Read Z : Next
If Z=0 : Z=NBK+16 : End If : Paste Bob E,F,Z
Else
If PREF(X) : Paste Bob E,F,Z : End If
End If
Next
Get Bob ZCR,ZB,0,0 To 111,64 : Screen ECR : Bob 1,,,ZB : Wait Vbl
For X=2 To 6 : Bob X,,,NBK+16 : Next
If CHOIX=0 : Screen ZCR
For Z=64 To 1 Step -4
ZZ=Min(2*Z,112)
Get Bob ZCR,ZB,0,0 To ZZ,Z : Screen ECR : Bob 1,40,73,ZB : Wait Vbl
Next
Bob 1,,,NBK+16 : Wait Vbl : Bob Off 1 : Wait Vbl
Else
Channel 1 To Bob 1 : Bob 1,,,Length(1) : Wait Vbl
If CHOIX=1
Amal 1,"M 112,0,28" : Amal On 1 : While Chanmv(1) : Wend
Else
Amal 1,"M -112,0,28" : Amal On 1 : While Chanmv(1) : Wend
End If
End If : Screen Close ZCR
Limit Bob : Amal Off : Bob Off : AJOUR : CLOCK[300,150]
If L$<>LANGUE$
If CHOIX=0
A$="Decors/Entree"+LANGUE$ : PASSECRAN[A$,1,1,1]
End If
If CHOIX=1
Load "banqueI/Titror"+LANGUE$+".ABK" : Paste Icon 20,48,TEST
End If
End If
BANQBI["",""]
End Proc
Procedure NETTOIE[BLK]
Update : Wait Vbl : Update Off
Bob Clear : Put Cblock BLK : Bob Draw : Screen Swap : Wait Vbl
Bob Clear : Put Cblock BLK : Bob Draw : Screen Swap : Wait Vbl
Update On
End Proc
Procedure AUTOBLOC[N,X,Y]
Update : Update Off : Wait Vbl
Bob Clear : Put Block N,X,Y : Bob Draw : Screen Swap : Wait Vbl
Bob Clear : Put Block N,X,Y : Bob Draw : Screen Swap : Wait Vbl
Update On
End Proc
Procedure ABLOC[N]
Update : Update Off : Wait Vbl
Bob Clear : Put Block N : Bob Draw : Screen Swap : Wait Vbl
Bob Clear : Put Block N : Bob Draw : Screen Swap : Wait Vbl
Update On
End Proc
Procedure AJOUR
Update : Wait Vbl : Update : Wait Vbl
End Proc
Procedure TIRE[M]
If M=0 Then SA$="" : Pop Proc
' Tire un nombre parmi M et nouveau dans SA$
M=M-1 : Repeat : I=1+Rnd(M) : Until Instr(SA$,Str$(I)+" ")=0
SA$=SA$+Str$(I)+" "
End Proc[I]
Procedure TIRB[M]
If M=0 Then SB$="" : Pop Proc
' Tire un nombre parmi M et nouveau dans SB$
M=M-1 : Repeat : I=1+Rnd(M) : Until Instr(SB$,Str$(I)+" ")=0
SB$=SB$+Str$(I)+" "
End Proc[I]
Procedure AFFECTE[DEB,NOMB,IMAGE]
' DEB : premier indice, NOMB : nombre total, premier compris
' IMAGE: l'image � affecter
Repeat : N=DEB+Rnd(NOMB-1) : Until 0=ZBI(N) : ZBI(N)=IMAGE
End Proc[N]
Procedure VIDE
Update : Bob Update Off : Wait Vbl
For N=1 To NB : Bob N,H(N),V(N),NBK+16 : Wait Vbl : Next
Update : Bob Update On
End Proc
Procedure PLACE
Update : Bob Update Off : Wait Vbl
For N=1 To NB : Bob N,H(N),V(N),ZBI(N) : Wait Vbl : Next
Update : Bob Update On
End Proc
Procedure VOISTEST
If(ETAPE>1) and(Screen=3)
DROITE[3,45]
Else
TPTS(TEST)=0 : METTOTAL["+",0,XT,YT] : DROITE[Screen,235] : DC=190
S=Screen : Screen Open 3,450,270,64,Lowres : Flash Off : Get Palette S
Screen To Front S : Screen Copy S,190,0,640,270 To 3,0,0
Screen Offset 3,85,0 : Screen Close S : Double Buffer
Colour 0,0 : Colour Back 0 : Wait Vbl : View
Erase 7 : Reserve As Chip Work 7,65000
A$="MRbruits/Brt4.sbk" : If Not(Exist(A$)) : A$="df0:Brt4.sbk" : End If
Load A$,7
End If
End Proc
Procedure POSEVAR
Screen Open 7,32,10,16,Lowres : Flash Off : Screen Hide 7 : Screen 7
For X=1 To 5 : Doke Phybase(0)+2*(X-1),PREF(X) : Next
For X=1 To 4 : Doke Phybase(0)+8+2*X,TPTS(X) : Next
End Proc
Procedure PRENDVAR
Screen Hide 7 : Screen 7
For X=1 To 5 : PREF(X)=Deek(Phybase(0)+2*(X-1)) : Next
For X=1 To 4 : TPTS(X)=Deek(Phybase(0)+8+2*X) : Next
Data "Ang","Ang","All","Fra","Esp","Ita","","","","","","","Jap"
Restore : For X=1 To PREF(3) : Read LANGUE$ : Next
Screen Close 7
End Proc
Procedure RETOUR
Erase 1 : Erase 2 : Del Block : Del Cblock
S=Screen : Screen Open 2,360,270,64,Lowres : Flash Off
Get Palette S : Screen To Front S
Screen Copy S,0,0,360,270 To 2,0,0 : Screen Close S
CLOCK[280,60] : Load Iff "Decors/Entree"+LANGUE$,1
Flash Off : Screen To Front 2
Colour 0,0 : Colour Back 0 : Wait Vbl : View
Screen 2 : Autoback 0 : Screen To Front 2 : N=0 : D=2
BRUIT[0,0,"antizoom"]
For X=0 To 130 Step 1 : Repeat
H1=X : H2=X+D : H4=350-X : H3=H4-D
V1=X : V2=X+D : V4=270-X : V3=V4-D
Screen Copy 1,H1,V1,H4,V2 To 2,H1,V1
Screen Copy 1,H3,V2,H4,V4 To 2,H3,V2
Screen Copy 1,H1,V3,H3,V4 To 2,H1,V3
Screen Copy 1,H1,V2,H2,V3 To 2,H1,V2
Wait Vbl : Screen Swap : Inc N
Until N>1 : Next
Screen Close 2
Colour 0,0 : Colour Back 0 : Wait Vbl : View
POSEVAR : Screen 1 : A$="A48.amos" : If Exist("df0:"+A$) Then A$="DF0:"+A$
Run A$
End Proc
'
Procedure XY
X0=0 : Y0=0 : Change Mouse 1 : Show On : Limit Mouse
Repeat
X=X Screen(X Mouse) : Y=Y Screen(Y Mouse)
If X<>X0 or Y<>Y0
Locate 35,1 : Print X;" " : Locate 35,2 : Print Y;" "
X0=X : Y0=Y
End If
K$=Inkey$ : Exit If K$<>""
Until Mouse Key
End Proc
Procedure VOIR
Pop Proc
Pen 21 : Locate 35,1 : Print X
Shoot : Do : Loop
End Proc